matrix-ops/IaC/nodes.tf

#
# Controller node resources
#

resource "openstack_networking_port_v2" "kubeport" {
  name                = "${var.controller_name}${count.index+1}-${replace(var.dns_suffix,".","-")}-port"
  # We create as many ports as there are instances created
  count               =  var.controller_instance_count
  network_id          = data.openstack_networking_network_v2.public.id
  # A list of security group ID
  security_group_ids  = [ 
                          data.openstack_networking_secgroup_v2.sshfromjumphosts.id, 
                          data.openstack_networking_secgroup_v2.allegress.id,
                          resource.openstack_networking_secgroup_v2.microk8s.id
                        ]
  admin_state_up      = "true"
}

resource "openstack_blockstorage_volume_v3" "kubecvolumeboot" {
  count                = var.controller_instance_count # size of cluster
  name                 = "${var.controller_name}${count.index+1}-${replace(var.dns_suffix,".","-")}-vol"
  description          = "OS volume for kubernetes control node ${count.index + 1}"
  size                 = 100
  image_id             = data.openstack_images_image_v2.debian12image.id
  enable_online_resize = true # Allow us to resize volume while attached.
}

resource "openstack_compute_instance_v2" "controller-nodes" {
  count           = var.controller_instance_count
  name            = "${var.controller_name}${count.index+1}.${var.dns_suffix}"
  flavor_name     = "${var.controller_instance_type}"
  key_pair        = "${var.keyname}"
  security_groups = [
                       data.openstack_networking_secgroup_v2.sshfromjumphosts.name,
                       data.openstack_networking_secgroup_v2.allegress.name,
                       resource.openstack_networking_secgroup_v2.microk8s.name
                    ]
  block_device {
    uuid             = resource.openstack_blockstorage_volume_v3.kubecvolumeboot[count.index].id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }
  scheduler_hints {
    group = openstack_compute_servergroup_v2.controllers.id
  }
  network {
    port   = resource.openstack_networking_port_v2.kubeport[count.index].id
  }
}

#
# Worker node resources
#

resource "openstack_compute_instance_v2" "worker-nodes" {
  count           = var.worker_instance_count
  name            = "${var.worker_name}-${count.index}.${var.dns_suffix}"
  flavor_name     = "${var.worker_instance_type}"
  key_pair        = "${var.keyname}"
  security_groups = ["microk8s", "Allow SSH from SUNET jumphosts", "Allow ssh from the world"]

  block_device {
    uuid                  = "5d24aca9-11be-4de1-9770-4a097d68f361"
    source_type           = "image"
    volume_size           = 20
    boot_index            = 0
    destination_type      = "volume"
    delete_on_termination = true
  }
  scheduler_hints {
    group = openstack_compute_servergroup_v2.workers.id
  }
  network {
    name = "public"
  }
}